perm filename PARSER[KA,SYS] blob
sn#224437 filedate 1976-07-19 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00005 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00002 00002 PARCLK, PARINT
C00008 00003 SUBTTL HERE WE SEARCH FOR REAL ERRORS.
C00018 00004 SUBTTL HERE WHEN A REAL ERROR IS FOUND. TELUSR, PARERF
C00031 00005 SUBTTL P2 PARITY ERROR INTERRUPT
C00036 ENDMK
C⊗;
;PARCLK, PARINT
BEGIN PARSER ↔ SUBTTL PARSER - PARITY ERROR SERVICE ROUTINE
;R. E. GORIN 7 AUG 72.
HISYS ;ASSEMBLE IN HIGH CORE
↑PARCLK: ;CALLED BY: SKIPE PARFLG
; PUSHJ P,PARCLK
CONO PI,APROFF ;TURN OFF APR TO AVOID TIMING ERRORS
SETOM P2RFLG ;SET SECOND LEVEL FLAG
SETZM PARFLG ;CLEAR PRIMARY FLAG
JRST PARIN0 ;JOIN PARITY ERROR INTERRUPT CODE
↑PARINT: ;HERE FROM APR CHANNEL FOR P1 PARITY ERROR,
IFKL10,<
EXCH TAC,KLUPT+KLPFPC
MOVEM TAC,APRCHL ;CH3 GETS ADDRESS OF PAGE FAULT
EXCH TAC,KLUPT+KLPFPC
>;IFKL10
PARIN0: MOVEM P,PARPSAV ;ASSUME WE HAVE NO AC'S.
MOVE P,APRPDL ;GET A STACK.
PUSHACS ;SAVE ALL THE AC'S
IFN FTXCOR,<
;
;CODE FROM HERE TO PARIX0 IS FOR GETHI UUO/PARITY ERROR SUPPRESSION HACK
;
SKIPE P2RFLG ;HERE BECAUSE OF P2?
JRST PARIX0 ;YES. BEHAVE NORMALLY
MOVE TAC,APRCHL ;PC
CONSO PI,7400 ;SKIP IF PI IN PROGRESS, CHANNELS 4-7
TLNN TAC,USRMOD
JRST PARIX0 ;FROM EXEC, ACT NORMALLY
MOVE TAC,JOB+P1PID
MOVE TAC,JBTPR2(TAC)
ANDI TAC,14
CAIN TAC,14
JRST PARIX1 ;PARITY ERROR SUPPRESSION HACK (GETHI)
PARIX0:
>;FTXCOR - END OF GETHI/PARITY ERROR SUPPRESSION
MOVEI PID,P1PID ;SET PROCESSOR IDENTIFICATION
PUSHJ P,DISCRLF ;START STUFFING THE TYPEOUT BUFFER
PUSHJ P,DISDATE ;ANNOUNCE THE DATE AND TIME
SKIPN P2RFLG ;IS THE PDP-6 HALUCINATING AGAIN?
JRST PARIN1 ;NO IT MUST BE P1
PUSHJ P,DISMES ;BLAME ON THE STONES
ASCIZ /πππππPDP-6 DETECTED PARITY ERROR. PC = /
MOVE TAC,AP2CHL ;GET THE PC OF PDP-6'S ERROR.
IFE FTPAGER,<
TLNE TAC,USRMOD ;IS THIS IN USER MODE?
TRNN TAC,777760 ;YES. IS THIS ABOVE THE AC'S
JRST PARIN3 ;EXEC MODE OR RUNNING IN THE AC'S
HRRZ TAC1,LASTPR+P2PID ;GET CURRENT RELOCATION DATA
ANDI TAC1,776000 ;LOWER PART OF THE RELOCATION ONLY
ADDI TAC,(TAC1) ;ADD RELOCATION
>;NOT FTPAGER
JRST PARIN3 ;SAVE ERROR PC AND PRINT IT.
PARIN1: PUSHJ P,DISMES ;HERE FOR P1 PARITY ERROR
ASCIZ /πππππPARITY ERROR. PC = /
MOVE TAC,APRCHL
IFE FTPAGER,<
TLNE TAC,USRMOD ;IS THIS IN USER MODE?
TRNN TAC,777760 ;YES. IS THIS ABOVE THE AC'S
JRST PARIN3 ;EXEC MODE OR RUNNING IN THE AC'S
TRNN TAC,400000 ;POSSIBLE UPPER?
JRST PARIN2 ;NO THIS HAS TO BE A LOWER.
HRRZ TAC1,APRCHL ;GET THE USER MODE PC.
HLRZ AC3,LASTPR+P1PID ;GET THE CURRENT PROTECTION
TRO AC3,1777 ;TURN ON LOW ORDER BITS.
CAIG TAC1,(AC3) ;IS THIS PC IN THE LOWER?
JRST PARIN2 ;YES
CAIGE AC3,400000 ;IS THE LOWER GREATER THAN 128K (HA HA)
MOVEI AC3,400000 ;NO. THIS IS THE NUMBER TO SUBTRACT FROM PC
SUBI TAC,(AC3) ;LEAVING RELATIVE PC IN UPPER
HRRZ AC3,LASTPR+P1PID ;GET THE RELOCATION
LSH AC3,=9 ;SHIFT IT TO SELECT RELOC OF UPPER.
ANDI AC3,776000 ;MASK
TRC AC3,400000 ;UN-BUGGER IT -- RPH 2-7-73
ADDI TAC,(AC3) ;ADD IT TO THE PC.
MOVEM TAC,ERRPC ;SAVE ERROR PC.
PUSHJ P,DISMES
ASCIZ /#/ ;DENOTE BY THIS A PC IN THE UPPER
MOVE TAC,ERRPC ;RESTORE ERROR PC AND GO PRINT IT
JRST PARIN4
PARIN2: HRRZ TAC1,LASTPR+P1PID ;GET CURRENT RELOCATION DATA
ANDI TAC1,777000 ;LOWER PART OF RELOCATION
ADDI TAC,(TAC1) ;ADD RELOCATION
>;NOT FTPAGER
PARIN3: MOVEM TAC,ERRPC ;SAVE ERROR PC.
;DROPS THROUGH
SUBTTL HERE WE SEARCH FOR REAL ERRORS.
;DROPS THROUGH
PARCON←←1B19
PARIN4: PUSHJ P,DISOCT ;WRITE THE ERROR PC
PUSHJ P,DISCRLF ;AND A CRLF
NOKL10,<
CONO PI,PARCON ;TURN OFF ERROR FLAG.
>;NOKL10
IFKL10,<
CONI APR,TAC
ANDI TAC,4707
CONO APR,KLCLRF(TAC) ;CLEAR ERRORS (KEEP PIA)
>;IFKL10
SETOM ERRLOC ;SET TO SIGNIFY NONE FOUND YET.
SETOM LASLOS ;JOB NUMBER OF LAST LOSER FOUND.
SETZB TAC1,PARSJN
SETZM SYSERR ;ASSUME NO ERRORS SYSTEM CORE.
MOVE TAC,ERRPC ;GET THE ERROR PC
TLNE TAC,USRMOD ;USER MODE?
JRST PARIN5 ;YES.
SETOM SYSERR ;EXEC MODE. PROBABLE SYSTEM ERROR.
ANDI TAC,-1 ;PC ONLY
CAIE TAC,SHFBLT ;IS THIS THE BLT IN THE SHUFFLER?
CAIN TAC,SHFBLT+1 ;OR POSSIBLY HERE.
MOVE TAC1,PARSJB ;SHUFFLE OPERATION. GET THE JOB NUMBER
MOVEM TAC1,PARSJN ;SET FLAG IF A SHUFFLER OPERATION.
CAIL TAC,IOPPTS ;IS THE PC IN IOPERR?
CAILE TAC,IOPPTS+3
JRST .+2 ;NOT IN IOPERR
SETOM IOPMPF ;SET FLAG FOR PROBABLE IOP PARITY ERROR
PARIN5: SETZM ERRJOB ;ZERO OUR TABLE OF LOSING JOBS
SETZM ERRJOB+1 ;
REPEAT 0,< CONI APR,TAC ;FLUSHED 12/73 ;GET STATE OF SYS WR REF KLUGE
HRRM TAC,SYSERR ;SAVE IN RIGHT SIDE OF SYSERR.
DATAO PTR,[0] ;DISABLE SYS WR REF KLUGE.
>;REPEAT 0
;SEARCH PHYSICAL MEMORY FOR PARITY ERRORS
IFN FTEXPG,<
IFKL10,<
PUSH P,KLUPT+KLPFNP
MOVE TAC,[PCU,,PARTRP]
MOVEM TAC,KLUPT+KLPFNP
>;IFKL10
LDB TAC,[POINT 13,TMEMSIZ,26] ;NUMBER OF PAGES OF REAL CORE
CAILE TAC,GOODPG
MOVEI TAC,GOODPG ;ONLY SCAN "GOOD" PAGES
MOVNI TAC,(TAC)
MOVSI TAC,(TAC) ;-NUMBER OF PAGES,,PAGE 0
PARL0: MOVSI AC3,160040 ;READ WRITE EXECUTE ACCESS
HRRI AC3,(TAC) ;PHYSICAL PAGE NUMBER
MOVEM AC3,EXPGT+PAREXP ;STORE IN EXEC PAGE TABLE
NOKL10,<CONO PAG,1 >;NOKL10 FLUSH ARS
IFKL10,<CONO KLPAG,@KLPCON >;IFKL10 FLUSH HARDWARE PAGE MAP
MOVE TAC1,[-1000,,PAREXP⊗9] ;AOBJN WORD FOR ONE PAGE
NOKL10,<
PARL1: MOVE 0,(TAC1)
CONSZ PI,PARCON
JRST PARL3 ;JUMP ON PARITY ERROR
>;NOKL10
IFKL10,<
↑PARL1: CAMA (TAC1) ;REFERENCE MEMORY, DON'T CLOBBER AC, SKIP IF NO ERR
JRST PARL3 ;PAGE FAULT HANDLER RETURNS HERE ON AR/ARX PAR ERR
; WITH GOOD PARITY NOW WRITTEN IN THE LOCATION
>;IFKL10
PARL2: AOBJN TAC1,PARL1 ;RETURN HERE AFTER ERROR
AOBJN TAC,PARL0 ;ADVANCE TO THE NEXT PAGE
SETZM EXPGT+PAREXP
NOKL10,<CONO PAG,1 >;NOKL10 CLEAR ARS
IFKL10,<
CONO KLPAG,@KLPCON ;CLEAR HARDWARE MAP
POP P,KLUPT+KLPFNP ;RESTORE PAGE FAULT TRAP NEW PC
>;IFKL10
JRST PARL5 ;ALL DONE.
PARL3: PUSH P,TAC
PUSH P,TAC1
NOKL10,<
MOVEM 0,(TAC1) ;STORE GOOD PARRITY
CONO PI,PARCON ;SHUT OFF ERROR INDICATORS
>;NOKL10
IFKL10,<
MOVE 0,(TAC1) ;READ GOOD PARITY TO AC
PUSH P,TAC
CONI APR,TAC
ANDI TAC,4707
CONO APR,KLCLRF(TAC) ;CLEAR ERROR
POP P,TAC
>;IFKL10
DPB TAC,[POINT 13,TAC1,26] ;STORE PHYSICAL ADDRESS
TLZ TAC1,777760 ;FLUSH EXTRANEOUS BITS
PUSHJ P,PARERF ;SERVICE THIS ERROR
POP P,TAC1
POP P,TAC
JRST PARL2
>;IFN FTEXPG
IFE FTEXPG,<
IFKL10,<.FATAL YOU'D BETTER REWRITE THIS>
MOVEI TAC1,20 ;IGNORE ACS
PARL1: CAM (TAC1) ;REFERENCE MEMORY
NOKL10,<CONSZ PI,PARCON ;ANY ERROR? >;NOKL10
IFKL10,<CONSZ APR,4700 ;ANY ERROR? >;IFKL10
JRST PARL3 ;YES.
PARL2: ADDI TAC1,1
CAMGE TAC1,RMEMSIZ ;ENOUGH?
JRST PARL1 ;NO.
JRST PARL5
NOKL10,<
PARL3: CONO PI,PARCON ;SHUT OFF ERROR INDICATORS
MOVE 0,(TAC1) ;STORE GOOD PARITY IN MEMORY.
MOVEM 0,(TAC1)
>
IFKL10,<
PARL3: MOVES (TAC1) ;WRITE GOOD PARITY
MOVE 0,(TAC1) ;GET DATA
CONI APR,TAC
ANDI TAC,4707
CONO APR,KLCLRF(TAC)
>;IFKL10
PUSH P,TAC1 ;SAVE COUNTER
HRRZ TAC1,TAC1
PUSHJ P,PARERF ;SERVICE THIS ERROR
POP P,TAC1
JRST PARL2 ;AND RETURN TO LOOP
>;IFE FTEXPG
PARL5: SKIPL ERRLOC ;HAS THIS BEEN SET UP?
JRST PARL6 ;YES. WE MUST HAVE PRINTED SOMETHING
AOS NPARIN ;COUNT INDETERMINATE ERRORS
PUSHJ P,DISMES ;WE DIDN'T FIND ANY.
ASCIZ /LOCATION INDETERMINATE
/
PUSHJ P,ZSHAD ;ZERO SHADOW MEMORY IN CASE WE LOST THERE.
JFCL ;SKIPS IF NO FAST ACS
HRROS SYSERR ;CHECK THE SYSTEM. DEPT. OF REDUNDANCY DEPT.
PARL6:
MOVE TAC,SYSERR ;ERROR IN SYSTEM CORE?
REPEAT 0,< ;12/1/73
TRNE TAC,SWRENB ;WAS SYS WR REF KLUGE ENABLED?
DATAO PTR,[1] ;YES. RE-ENABLE IT
>
JUMPGE TAC,PARL7 ;JUMP IF ERROR WAS NOT IN SYSTEM
PUSHJ P,SYSFIX ;JUST IN CASE WE NEED THIS
JFCL ;NO ERROR
JFCL ;ERROR AND DIDN'T FIX
;ALL FIXED.
PARL7: PUSHJ P,DISCRLF
PARIX1:
NOKL10,<CONO PI,PARCON ;TURN OFF PAR ERR FLAG IN CASE GETHI>;NOKL10
IFKL10,<CONI APR,TAC
ANDI TAC,4707
CONO APR,KLCLRF(TAC) ;CLEAR ERROR FLAGS
MOVEI TAC,7740
HRRM TAC,KLPARC
CONO APR,KLENBF+4700+APRCHN ;RE-ENABLE EVERYTHING
>;IFKL10.
POPACS ;RESTORE ALL THE AC'S THAT WE SAVED
MOVE P,PARPSAV ;GET STACK BACK (OR WHATEVER WAS IN IT).
SKIPN P2RFLG ;WAS THIS THE PDP-6 HACKING?
JRST PARL9 ;NO. THIS WAS THE PDP-10
SETZM P2RFLG ;CLEAR ERROR FLAG
CONO PI,APRON ;RESTORE INTERRUPT SYSTEM
POPJ P, ;RETURN TO P1 CLOCK LEVEL
PARL9: CONO PI,APRON ;TURN ON THE APR CHANNEL
JEN @APRCHL ;DISMISS ERROR INTERRUPT
IFKL10,<
PARTRP: CONSZ PI,60000
HALT . ;PAGE FAULT FROM CH1 OR CH2???
LDB AC1,[POINT 5,KLUPT+KLPFW,5] ;GET FAILURE TYPE
CAIE AC1,36
CAIN AC1,37
JRST PARTR1
PUSHACS
PUSHJ P,DISMES
ASCIZ \PAGE FAULT OTHER THAN AR/ARX PAR ERR AT PARTRP
\
PUSHJ P,DISFLU
PUSHJ P,DDTCAL
HALT .-1
PARTR1: AOS KLUPT+KLPFPC ;FORGIVE US...SEE PARL1
DATAI KLPAG,DAT ;SAVE AC CONTEXT
CONI PI,AC3
ANDI AC3,PION
TLZ DAT,300000
MOVE AC1,DAT
TLO AC1,700
CONO PI,PIOFF
DATAO KLPAG,AC1 ;KEEP CURRENT CONTEXT, SET PREV TO 7
XCTR XR,[MOVE AC2,0] ;GET GOOD PARITY DATA FROM AC BLK 7 REG 0
DATAO KLPAG,DAT ;PUT AC CONTEXT BACK
CONO PI,(AC3) ;PUT PION BACK THE WAY IT WAS
HRRZ DAT,KLUPT+KLPFW
MOVEM AC2,(DAT) ;STORE DATA WITH GOOD PARITY
JRST 2,@KLUPT+KLPFPC
>;IFKL10
SUBTTL HERE WHEN A REAL ERROR IS FOUND. ; TELUSR, PARERF
PARERF: MOVE TAC,ERRLOC ;REMEMBER OLD VALUE OF ERRLOC
MOVEM 0,ERRDAT ;SAVE ERROR DATA
MOVEM TAC1,ERRLOC ;SAVE PRESENT ERROR LOCATION
AOS NPARER ;COUNT NUMBER OF PARITY ERRORS
JUMPGE TAC,PARER1 ;JUMP IF THIS IS NOT THE FIRST TIME HERE.
PUSHJ P,DISMES ;PUT OUT THE HEADING
ASCIZ / LOC DATA RELOC NAME(J)
/
PARER1: MOVE TAC,ERRLOC ;GET LOCATION
PUSHJ P,DISADR ;WRITE LOCATION
PUSHJ P,DISMES ;WRITE 2 SPACES
ASCIZ / /
MOVE TAC,ERRDAT ;GET DATA
PUSHJ P,DISOCH ;WRITE LOSING DATA AS OCTAL HALF WORDS
PUSHJ P,DISTAB ;PUT NEXT THING UNDER HEADING
LDB DSER,[POINT 13,ERRLOC,26] ;PAGE NUMBER OF ERROR (LOC = DSER)
PUSHJ P,CORGBP ;MAKE A BYTE POINTER TO CORTAB
LDB J,TAC ;LOAD JOB NUMBER INTO J
CAIGE J,JOBN ;IS THIS A SPECIAL CODE?
JUMPG J,PARER4 ;JUMP IF CORE IS ASSIGNED TO NORMAL JOB
SKIPE PARSJN ;ARE WE IN A SHUFFLE?
JUMPE J,PARR4B ;YES. JUMP IF ALLEGED UNASSIGNED CORE.
PARR1A: CAMN J,LASLOS ;SAME AS LAST LOSER?
JRST DISCRLF ;YES. JUST TYPE A CRLF AND RETURN
MOVEM J,LASLOS ;SAVE CODE FOR LAST LOSER
JUMPG J,PARER2 ;JUMP IF NOT UNASSIGNED CORE
PUSHJ P,DISMES ;FOR UNASSIGNED CORE
ASCIZ /UNUSED
/
POPJ P, ;RETURN LOOK FOR MORE.
PARER2: CAIE J,101 ;IS THIS THE SYSTEM?
JRST PARER3 ;NO. MUST BE FREE STORAGE.
HRROS SYSERR ;REMEMBER TO CHECKSUM THE SYSTEM
PUSHJ P,DISMES
ASCIZ /SYS
/
POPJ P,
PARER3: PUSHJ P,DISMES
ASCIZ /FS
/
POPJ P,
PARR4B: MOVE J,PARSJN ;JOB NUMBER OF GUY BEING SHUFFLED.
HRRZ TAC,PARBLK ;GET LOC OF OLD CORE
SUBI DSER,(TAC) ;MAKE RELATIVE LOCATION.
JUMPL DSER,PARR4C ;THIS ISN'T PART OF THE OLD CORE.
HLRZ TAC,PARBLK ;GET SIZE OF OLD CORE
CAILE DSER,(TAC) ;SKIP IF ERROR IS IN OLD SHUFFLED CORE.
PARR4C: MOVEI J,0
JUMPE J,PARR1A ;TREAT THIS AS UNUSED CORE.
PARER4: PUSH P,J ;SAVE JOB NUMBER
HRRZ TAC1,JBTPAG(J) ;PAGE NUMBER OF USER'S FIRST PAGE
LSH TAC1,=9 ;MAKE ADDRESS OF PAGE.
CAMN J,PARSJN ;THIS JOB SHUFFLE IN PROGRESS?
HRRZ TAC1,PARBLK ;YES. GET THE OLD JOB LOCATION.
HRRZ TAC,ERRLOC ;GET THE ERROR LOCATION
SUBI TAC,(TAC1) ;FORM THE USER RELATIVE ADDRESS
MOVEM TAC,RERLOC ;SAVE RELOCATED ERROR LOCATION.
PUSHJ P,DISLOC ;TYPE 6 CHARACTERS
MOVE J,(P) ;GET THE JOB NUMBER INTO J AGAIN
CAMN J,LASLOS ;SAME AS LAST TIME?
JRST PARR4A ;YES. DON'T TELL JOB NAME AGAIN
MOVEM J,LASLOS ;REMEMBER FOR NEXT TIME
PUSHJ P,DISTAB ;TYPE A TAB FOR SEPARATION
MOVE J,(P) ;MAKE SURE NO ONE CLOBBERS J.
PUSHJ P,DISJOB ;TYPE JOB NUMBER(JOB NAME)
CAME J,PARSJN ;IS THIS A SHUFFLE OPERATION?
JRST PARR4A
PUSHJ P,DISMES
ASCIZ / SHUFFLE/
PARR4A: PUSHJ P,DISCRLF
MOVE J,(P) ;RESTORE J (AGAIN)
MOVE TAC,JBTSTS(J) ;GET THE JOB STATUS WORD
TLNN TAC,JSEG ;IS THIS REALLY AN UPPER?
JRST PARER8 ;NO, JUST A SIMPLE LOWER.
PUSHJ P,MARKERR ;HAS THIS UPPER LOST BEFORE (OR IS IT FIXABLE)?
JRST TPOPJ ;YES. DON'T TELL LOWERS AGAIN
MOVEI TAC,400000 ;IN CASE OF A SEGMENT
ADDM TAC,RERLOC ;ADD 400000 TO RELOCATED ERROR ADDRESS
MOVEI J,JOBN-1 ;FOR ALL THE JOBS IN THE WORLD....
PARER5: LDB TAC,PSEGN ;GET THE JOB NUMBER OF THIS GUY'S UPPER
CAME TAC,(P) ;SAME AS THIS UPPER?
SOJG J,PARER5 ;NO.
JUMPLE J,PARER6 ;JUMP IF NO MORE USERS OF THIS UPPER
PUSH P,J ;SAVE THIS JOB ON THE STACK
PUSHJ P,TELUSR ;TELL A LOWER SEGMENT.
POP P,J
SOJG J,PARER5 ;DECREMENT J AND LOOK FOR MORE.
PARER6: POP P,J ;GET THE NUMBER OF THIS UPPER.
MOVE TAC,PRJPRG(J) ;GET A RIDICULOUS NAME
MOVEM TAC,JOBNAM(J) ;SAVE IT AS THE JOB NAME
POPJ P, ;NO ONE WILL ATTACH TO THIS AGAIN.
PARER8: PUSHJ P,TELUSR ;TELL THE USER ABOUT WHAT BEFELL HIM
JRST TPOPJ ;ADJUST STACK AND RETURN.
PARBUZ: JRST . ;BUZZ HERE UNTIL CH7 INTERRUPTS
TELUSR: PUSHJ P,MARKERR ;MARK THIS JOB HAS ERROR
POPJ P, ;HE'S BEEN TOLD BEFORE.
IFN FTDISK,< PUSHJ P,DSKFIX ;REPAIR GOBIT >
MOVSI TAC,INTPAR ;PICKUP PARITY ERROR ENABLE BIT
TDNE TAC,JBTMSK(J) ;MASKED OFF
TDNN TAC,JBTIEN(J) ;IS THIS USER ENABLED FOR THIS?
JRST TELUS1 ;NO. TELL HIM AND STOP HIM
CAMN J,JOB(PID)
SKIPN INTACT(PID)
JRST .+2
JRST TELUS1 ;CAN'T TAKE ANOTHER INTERRUPT
IORM TAC,JBTIRQ(J) ;SET PARINT BIT FOR THIS USER
SETOM INTREQ(PID) ;REQUEST A USER INTERRUPT
MOVE TAC1,RERLOC ;GET THE RELOCATED ADDRESS OF ERROR
MOVEM TAC1,INTDTM(J) ;SAVE IT FOR THIS USER.
CONSO PI,10000 ;CHANNEL 3?
JRST TELUSB ;NO. DON'T WORRY ABOUT DISMISSING TO CH7
MOVE TAC1,[PCU,,PARBUZ]
EXCH TAC1,APRCHL
TLNN TAC1,USRMOD
JRST TELUSA
MOVEM TAC1,USAVPC+P1PID ;HIS ACTUAL OLD PC
TELUSB: CONO PI,1B24!1(7-CLKCHN) ;REQUEST INTERRUPT ON CLOCK CHANNEL
HLLOS CLKFLG
POPJ P,
TELUSA: EXCH TAC1,APRCHL ;PUT BACK THE PC, IT WAS EXEC MODE
JRST TELUSB
;USER NOT ENABLED FOR PARITY ERROR. STOP HIM!
TELUS1: MOVE TAC,JBTLIN(J)
AOJE TAC,TELU1X ;JUMP IF DETACHED JOB
SKIPN TAC,TTYTAB-1(TAC) ;-1 BECAUSE OF AOJE
JRST TELU1X ;NO DDB (?)
MOVSI AC3,PTLIP ;CLEAR PTLOAD-IN-PROGRESS BIT
ANDCAM AC3,DEVIOS(TAC)
TELU1X: HRRZ TAC,RERLOC
HLRZ AC3,JBTPAG(J)
LSH AC3,=9
SUBI AC3,1 ;PROTECTION OF JOB
CAMN J,PARSJN ;SHUFFLED JOB?
HLRZ AC3,PARBLK ;YES. USE THIS ADDRESS.
CAILE TAC,(AC3) ;LOWER OR UPPER?
TLO TAC,400000 ;FLAG UPPER
MOVEM TAC,INTDTM(J) ;SAVE DATUM FOR LATER
HRLI J,TELUSC ;CLOCK LEVEL ROUTINE TO COMPLETE OUR WORK
CONO PI,PIOFF
IDPB J,CLKQ ;USE 1-TICK DPYSER CLOCK QUEUE
CONO PI,PION
ANDI J,-1 ;JOB NUMBER ONLY.
CONSZ PI,10000 ;CHANNEL 3?
CAME J,JOB+P1PID ;YES. IS THIS THE CURRENT JOB?
JRST TELU1Y ;NOT CURRENT JOB OR NOT CH3
MOVE TAC1,[PCU,,PARBUZ]
EXCH TAC1,APRCHL
TLNN TAC1,USRMOD
JRST TELU1Z ;OOPS. CAN'T STOP HIM IN EXEC MODE
MOVEM TAC1,USAVPC+P1PID ;HIS ACTUAL OLD PC FOR CH7
TELU1Y: CAMN J,PARSJN ;IS THIS JOB INSIDE BLT?
CONSZ PI,400 ;YES IN BLT. SKIP IF NOT CH7
JRST STOP1 ;NOT AT BLT OR IN SHUFFLER
JRST SETSTP ;CLEAR RUN IN JBTSTS SET QUEUE.
;JOB WAS AT MOVCOR IN CORE UUO. STOP AT UUO EXIT
TELU1Z: EXCH TAC1,APRCHL ;MUST DISMISS BACK TO EXEC MODE
JRST TELU1Y
;HERE AT CLOCK LEVEL TO FINISH FLUSHING LOSER
TELUSC: MOVEI J,(DAT)
PUSHJ P,TTYERR ;GET THE USER'S TTY
SKIPGE INTDTM(J) ;IN LOWER?
JRST TELUS2 ;NO. IT IS IN THE UPPER
PUSHJ P,INLMES ;STUFF DATA INTO TTY
ASCIZ /Parity error in your core image at location /
JRST TELUS3
TELUS2: PUSHJ P,INLMES
ASCIZ /Parity error in your upper segment at location /
TELUS3: HRRZ TAC,INTDTM(J) ;GET THE RELOCATED ERROR
PUSHJ P,OCTPNT ;TELL HIM THE LOCATION.
PUSHJ P,PRCRCC
PUSHJ P,TTYSTR ;START THE USER'S TTY TYPING
MOVE TAC,JBTSTS(J)
TLNE TAC,JLOG ;LOGGED IN?
POPJ P, ;YES. LEAVE NOW.
JRST ESTOP ;NO. KILL THE PHANTOM
;CALL THIS ROUTINE TO SEE IF HE NEEDS TO BE TOLD
;WILL TRY TO REPEAT SWAPIN IF POSSIBLE
MARKERR: ;PUSHJ HERE TO MARK JOB IN J AS HAVING ERROR.
MOVEI TAC,(J) ;GET JOB NUMBER
MOVEI TAC1,0
LSHC TAC,-5
ROT TAC1,5
MOVEI AC3,1
ROT AC3,-20(TAC1) ;ROTATE TO AN UNUSUAL POSITION
TDNE AC3,ERRJOB(TAC) ;IS THIS BIT SET ALREADY?
POPJ P, ;YES.
IORM AC3,ERRJOB(TAC) ;NO. SET IT
MOVE TAC,RERLOC
HLRZ AC3,JBTPAG(J)
LSH AC3,9
SUBI AC3,1 ;PROTECTION OF JOB
CAIG TAC,(AC3) ;CAN'T FIX HIS UPPER HERE
SKIPE STIME(J) ;NOW SEE IF THE SWAPPER CAN FIX IT
JRST CPOPJ1 ;MODIFIED SINCE SWAPIN
HLRZ TAC,JBTSWP(J)
JUMPE TAC,CPOPJ1 ;NOT SWAPPED OUT YET
SKIPN XJOB(J)
AOS XJOB
AOS XJOB(J) ;THIS SHOULD MAKE IT GET SWAPPED
POPJ P,
;CLEAR GOBIT SO JOB DOESN'T HANG. (CALLED ALSO FOR SWAP READ ERROR)
↑DSKFIX:SKIPA DDB,[DSKDDB] ;INITIALIZE SCAN
DSKFX1: ANDCAM TAC1,DEVIOS(DDB) ;FLUSH ACTIVE BITS
PUSHJ P,STOPC2 ;(CLKSER). LOCATE ACTIVE DSK DDB FOR JOB
JRST DSKFX1 ;FLUSH GOBIT, CONTINUE SCAN
POPJ P, ;NO MORE ACTIVE DSK DDBS
SUBTTL P2 PARITY ERROR INTERRUPT
LOSYS ;ASSEMBLE IN LOW CORE FOR THE PDP-6
↑P2RINT:
CONO PI,@P2RCON ;ZERO ERROR BIT
MOVEM TAC,P2SA ;SAVE TAC
MOVEI TAC,17 ;SCAN THE AC'S
MOVES (TAC)
SOJGE TAC,.-1 ;LOOP
CONSZ PI,@P2RCON ;IS THAT WHERE IT IS?
JRST PARACS ;YES
SETOM PARFLG ;NO, TELL THE TEN
MOVE TAC,PARFLG ;WAIT FOR THE PDP-10 TO SEE THE FLAG
JUMPN TAC,.-1 ;WAIT UNTIL IT GOES ZERO
MOVE TAC,P2RFLG ;WAIT FOR THE PDP-10 TO FINISH PARSER
JUMPN TAC,.-1 ;
JRST P2ROUT ;RESTORE TAC AND DISMISS
PARACS: CONO PI,@P2RCON ;CLEAR PARITY ERROR
P2ROUT: MOVE TAC,P2SA ;RESTORE ACCUMULATOR
JEN @AP2CHL ;DISMISS INTERRUPT
BEND PARSER